%==========================================================================
%
%       Experimental, add one axiom to A000272R.fnd.
%       Seems to give factorials, A000142. (1,1,2,6,24,120,720,...)
%
%       Here we fix the element 0 as a "root" to which
%       "all the small trees of the forest" are connected,
%       so we get the same sequence as without that trick,
%       but shifted once right.
%
% See also:
%
% http://www.research.att.com/cgi-bin/access.cgi/as/njas/sequences/eisA.cgi?Anum=A000142
% http://mathworld.wolfram.com/PartialOrder.html
% http://www.iki.fi/~kartturi/matikka/ModFin/A000272.fnd
% http://www.iki.fi/~kartturi/matikka/ModFin/A000272Rv2.fnd
% http://www.iki.fi/~kartturi/matikka/ModFin/A001035R.fnd
%
% http://arp.anu.edu.au/~jks/finder.html
%
%==========================================================================

sort {
        ELEM
        cardinality = 5
}


function {
        e:      ELEM,ELEM -> bool.
        f:      ELEM -> ELEM { cut }
}


clause {
        e(x,x) -> FALSE.                        % Irreflexive.
        e(x,y) -> FALSE = e(y,x).               % Asymmetric.
        FALSE = e(x,y); FALSE = e(y,z); e(x,z). % Transitive.
        FALSE = e(x,z); FALSE = e(y,z); x=y; e(x,y); e(y,x). % IF (x<z)&(y<z)&(x!=y) THEN x<y OR y<x.
        x -> e(f(x),x).                         % Every element, except the root (0) must have another element "less" than it.
        e(x,y) -> x < y.                        % Experimental: require total ordering of the labels in each chain.
}

setting {
        verbosity stats: full
        stack: maximal
}


end